home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Software Vault: The Games Collection 1
/
software vault.zip
/
software vault
/
CDR09
/
_BANDIT_.ZIP
/
BANDIT.BAS
Wrap
BASIC Source File
|
1993-06-10
|
2KB
|
97 lines
10 PRINT "WELCOME TO YASSER ZIA'S BANDIT"
20 REM
30 GOSUB 9010
35 DIM R(3)
40 PRINT "SO, WANT A DESCRIPTION OR WHAT? (Y OR N)";
50 INPUT Q$
60 IF Q$ = "N" THEN 120
70 IF Q$ = "Y" THEN 110
80 PRINT "COME ON DUDE! ANSWER: Y FOR YES"
90 PRINT " OR N FOR NO..."
100 GOTO 40
110 GOSUB 1010
120 LET T = 0
130 PRINT
140 PRINT "GET READY TO LOSE PAL!"
150 PRINT "HOW MUCH YOU WANNA BET?";
160 INPUT Q
170 IF Q > 0 THEN 200
180 PRINT "YOU HAVE TO BET TO PLAY YOU DING DONG!"
190 GOTO 150
200 IF Q < 501 THEN 230
210 PRINT "ARE YOU NUTS DUDE?! BE REASONABLE!"
220 GOTO 130
230 IF Q > .99 THEN 250
240 PRINT "YOU'RE A CHEAPSKATE DUDE!"
250 GOSUB 3010
260 GOSUB 4010
270 LET T = T + Q
280 IF T < 0 THEN 350
290 IF T > 0 THEN 380
300 PRINT "GONNA CHICKEN OUT YET DUDE? (Y OR N)"
310 INPUT Q$
320 IF Q$ = "N" THEN 140
330 PRINT "*** SEE YOU AROUND.......CHUMP ***"
340 END
350 PRINT "ALL RIGHT PUNK, COUGH IT UP!"; ABS(T)
360 IF ABS(T) < 200 THEN 140
370 GOTO 300
380 PRINT "YOU'VE WON: $"; T
1000 GOTO 360
1010 PRINT "THIS GAME SIMULATES A"
1020 PRINT " ONE-ARMED BANDIT (THAT'S"
1030 PRINT " A SLOT MACHINE FOR YOU AMEBAES WHO DON'T KNOW)."
1040 PRINT "BET ON EACH PULL - UP TO $200 BUCKS"
1050 PRINT "3 JACKPOTS GIVES YOU 20 X THE BET"
1060 PRINT "3 BARS GIVES YOU 10 X THE BET"
1070 PRINT "3 OF ANYTHING ELSE GIVES YOU 5 X THE BET"
1080 PRINT "2 OF THE OTHERS GIVES YOU DOUBLE THE BET"
3000 RETURN
3010 REM "FETCH THE FRUITS BUDDY"
3020 DATA JACKPOT, BELL, PLUM
3030 DATA ORANGE, LEMON, GRAPE
3040 DATA CHERRY, APPLE, MELON
3050 DATA BAR
3060 FOR I = 1 TO 3
3070 LET R = INT(10 * RND(1)) + 1
3080 LET R(I) = R
3090 FOR J = 1 TO R
3100 READ X$
3110 NEXT J
3120 RESTORE
3130 PRINT TAB(I * 10 - 10); X$;
3140 NEXT I
3150 PRINT
4000 RETURN
4010 REM "FIGURE WIN AMOUNT"
4020 IF R(1) + R(2) + R(3) = 3 THEN 4110
4030 IF R(1) + R(2) + R(3) = 30 THEN 4090
4040 FOR I = 1 TO 2
4050 IF R(3) <> R(I) THEN 4130
4060 NEXT I
4070 LET Q = 5 * Q
4080 RETURN
4090 LET Q = 10 * Q
4100 RETURN
4110 LET Q = 20 * Q
4120 RETURN
4130 IF R(3) = R(1) THEN 4180
4140 IF R(3) = R(2) THEN 4180
4150 IF R(1) = R(2) THEN 4180
4160 LET Q = 0 - Q
4170 RETURN
4180 LET Q = Q * 2
9000 RETURN
9010 REM "RANDOM NUMBER ROUTINE"
9020 LET Z = RND(1)
9030 RETURN